ActionScript3.0 ビットマップ

package{
  import flash.display.Loader;
  import flash.display.Sprite;
  import flash.display.Bitmap;
  import flash.display.BitmapData;
  import flash.events.Event;
  import flash.events.ProgressEvent;
  import flash.net.URLRequest;
  import flash.text.TextField;

[SWF(width="300", height="200", backgroundColor="0xFFFFFF")]

  public class Main extends Sprite 
  {
    private const url:String = "http://mniwa.web.fc2.com/mail.png";
    private var loader:Loader;
    private var text_field:TextField;
    private var bitmap:Bitmap;

    public function Main():void
    {
      // テキストフィールドの準備
      text_field = new TextField();
      text_field.x = 0;               // x 座標
      text_field.y = 0;               // y 座標
      text_field.width = 300;         // 幅
      text_field.height = 100;        // 高さ
      addChild(text_field);

      // URL リクエストオブジェクトの準備
      var urlRequest:URLRequest;
      urlRequest = new URLRequest(url);

      // ローダーの準備
      loader = new Loader();
      loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgress);
      loader.contentLoaderInfo.addEventListener(Event.OPEN, onOpen);
      loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);

      // URL で指定された場所から画像を読み込む
      loader.load(urlRequest);
    }

    private function onProgress(e:ProgressEvent):void 
    {
      text_field.appendText("onProgress : ");
      text_field.appendText(e.bytesTotal + " バイト中 ");
      text_field.appendText(e.bytesLoaded + " バイト読み込み完了\n");
    }

    private function onOpen(e:Event):void 
    {
      text_field.appendText("onOpen : ロード開始\n");
    }

    private function onComplete(e:Event):void 
    {
      text_field.appendText("onComplete : ロード完了\n");

      var bmd:BitmapData;
      bmd = new BitmapData(loader.width, loader.height);
      bmd.draw(loader);
      bitmap = new Bitmap(bmd);
      bitmap.x = 100;
      bitmap.y = 100;
      addChild(bitmap);
    }
  }
}